В статье рассказывается о том как самостоятельно произвести очистку серверного кэша 1С:Предприятие 8.3 для клиент-серверного режима работы.
Способ №1 - очистка серверного кэша 1С с помощью скрипта
По умолчанию кэш сеансовых данных для сервера 1С:Предприятия x64 находится по такому пути:
C:\Program Files\1cv8\srvinfo\reg_1541\snccntx*
Важно! Перед очисткой серверного кэша обязательно необходимо остановить службу сервера 1С.
Файлы по указанному пути можно удалить вручную, либо воспользоваться скриптами:
@echo off
chcp 1251
SET SERVICE_1C_NAME="1C:Enterprise 8.3 Server Agent (x86-64)"
SET SERVICE_RAS_NAME="1C:Enterprise 8.3 Remote Administration Server Agent"
SET CNTX_PATH="C:\Program Files\1cv8\srvinfo\reg_1541"
SET PFL_PATH="C:\ProgramData\1C\1cv8"
SET TEMP_PATH="%TEMP%"
::#################################################
::Остановка службы сервера предприятия 1С x64
::#################################################
SC STOP %SERVICE_1C_NAME%
SC STOP %SERVICE_RAS_NAME%
TIMEOUT 10
::#######################################################################################
::Принудительное завершение процессов сервера 1С, если они не завершились корректно
::#######################################################################################
TASKKILL /F /IM "rphost.exe"
TASKKILL /F /IM "rmngr.exe"
TASKKILL /F /IM "ragent.exe"
TASKKILL /F /IM "ras.exe"
TIMEOUT 5
::###################################################
::Удаление сеансовых данных сервера предприятия
::###################################################
DEL /Q /F /S %CNTX_PATH%\snccntx*
DEL /Q /F %PFL_PATH%\*.pfl
DEL /Q /F /S %TEMP_PATH%\*.*
::##################################
::Запуск службы сервера 1С x64
::##################################
SC START %SERVICE_1C_NAME%
SC START %SERVICE_RAS_NAME%
либо
@echo off
chcp 1251
SET SERVICE_1C_NAME="1C:Enterprise 8.3 Server Agent (x86-64)"
SET SERVICE_RAS_NAME="1C:Enterprise 8.3 Remote Administration Server Agent"
SET CNTX_PATH="C:\Program Files\1cv8\srvinfo\reg_1541"
::SET PFL_PATH="C:\ProgramData\1C\1cv8"
::SET TEMP_PATH="%TEMP%"
::#################################################
::Остановка службы сервера предприятия 1С x64
::#################################################
net stop %SERVICE_1C_NAME%
net stop %SERVICE_RAS_NAME%
::#######################################################################################
::Принудительное завершение процессов сервера 1С, если они не завершились корректно
::#######################################################################################
TASKKIll /F /FI "IMAGENAME eq rphost*"
TASKKIll /F /FI "IMAGENAME eq rmngr*"
TASKKIll /F /FI "IMAGENAME eq ragent*"
TASKKIll /F /FI "IMAGENAME eq ras*"
::############################################################
::Удаление пользовательского кэша 1С (раскомментировать при необходимости)
::############################################################
::#@FOR /D %%i in ("C:\Users\*") do (
::#@FOR /D %%j in ("%%i\Local settings\Application data\1C\1Cv8\????????-????-????-????-????????????") do rd /s /q "%%j"
::#@FOR /D %%j in ("%%i\AppData\Roaming\1C\1Cv8\????????-????-????-????-????????????") do rd /s /q "%%j"
::#)
::###################################################
::Удаление сеансовых данных сервера предприятия
::###################################################
for /d %%a in ("%CNTX_PATH%\snccntx*") do rd /s /q "%%a"
::DEL /Q /F %PFL_PATH%\*.PFL
::DEL /Q /F /S %TEMP_PATH%\*.*
::##################################
::Запуск службы сервера 1С x64
::##################################
net start %SERVICE_1C_NAME%
net start %SERVICE_RAS_NAME%
Также можно скачать готовый батник. Он сам останавливает службу 1С, очищает и после снова запускает службу 1С Агент.
скачать RAR
